Mercurial > hg-old > index.cgi
comparison m4/gnulib-common.m4 @ 421:3c2e1f24cc7d 3.0-beta2
Added generated files for release
author | lost@l-w.ca |
---|---|
date | Sun, 19 Sep 2010 01:33:24 -0600 |
parents | |
children |
comparison
equal
deleted
inserted
replaced
420:7366deedfa85 | 421:3c2e1f24cc7d |
---|---|
1 # gnulib-common.m4 serial 11 | |
2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc. | |
3 dnl This file is free software; the Free Software Foundation | |
4 dnl gives unlimited permission to copy and/or distribute it, | |
5 dnl with or without modifications, as long as this notice is preserved. | |
6 | |
7 # gl_COMMON | |
8 # is expanded unconditionally through gnulib-tool magic. | |
9 AC_DEFUN([gl_COMMON], [ | |
10 dnl Use AC_REQUIRE here, so that the code is expanded once only. | |
11 AC_REQUIRE([gl_00GNULIB]) | |
12 AC_REQUIRE([gl_COMMON_BODY]) | |
13 ]) | |
14 AC_DEFUN([gl_COMMON_BODY], [ | |
15 AH_VERBATIM([isoc99_inline], | |
16 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports | |
17 the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of | |
18 earlier versions), but does not display it by setting __GNUC_STDC_INLINE__. | |
19 __APPLE__ && __MACH__ test for MacOS X. | |
20 __APPLE_CC__ tests for the Apple compiler and its version. | |
21 __STDC_VERSION__ tests for the C99 mode. */ | |
22 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__ | |
23 # define __GNUC_STDC_INLINE__ 1 | |
24 #endif]) | |
25 AH_VERBATIM([unused_parameter], | |
26 [/* Define as a marker that can be attached to declarations that might not | |
27 be used. This helps to reduce warnings, such as from | |
28 GCC -Wunused-parameter. */ | |
29 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7) | |
30 # define _GL_UNUSED __attribute__ ((__unused__)) | |
31 #else | |
32 # define _GL_UNUSED | |
33 #endif | |
34 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name | |
35 is a misnomer outside of parameter lists. */ | |
36 #define _UNUSED_PARAMETER_ _GL_UNUSED | |
37 ]) | |
38 ]) | |
39 | |
40 # gl_MODULE_INDICATOR([modulename]) | |
41 # defines a C macro indicating the presence of the given module. | |
42 AC_DEFUN([gl_MODULE_INDICATOR], | |
43 [ | |
44 AC_DEFINE([GNULIB_]translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1], | |
45 [Define to 1 when using the gnulib module ]$1[.]) | |
46 ]) | |
47 | |
48 # m4_foreach_w | |
49 # is a backport of autoconf-2.59c's m4_foreach_w. | |
50 # Remove this macro when we can assume autoconf >= 2.60. | |
51 m4_ifndef([m4_foreach_w], | |
52 [m4_define([m4_foreach_w], | |
53 [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])]) | |
54 | |
55 # AC_PROG_MKDIR_P | |
56 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P. | |
57 # Remove this macro when we can assume autoconf >= 2.60. | |
58 m4_ifdef([AC_PROG_MKDIR_P], [], [ | |
59 AC_DEFUN_ONCE([AC_PROG_MKDIR_P], | |
60 [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake | |
61 MKDIR_P='$(mkdir_p)' | |
62 AC_SUBST([MKDIR_P])])]) | |
63 | |
64 # AC_C_RESTRICT | |
65 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61, | |
66 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++ | |
67 # works. | |
68 # This definition can be removed once autoconf >= 2.62 can be assumed. | |
69 AC_DEFUN([AC_C_RESTRICT], | |
70 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict], | |
71 [ac_cv_c_restrict=no | |
72 # The order here caters to the fact that C++ does not require restrict. | |
73 for ac_kw in __restrict __restrict__ _Restrict restrict; do | |
74 AC_COMPILE_IFELSE([AC_LANG_PROGRAM( | |
75 [[typedef int * int_ptr; | |
76 int foo (int_ptr $ac_kw ip) { | |
77 return ip[0]; | |
78 }]], | |
79 [[int s[1]; | |
80 int * $ac_kw t = s; | |
81 t[0] = 0; | |
82 return foo(t)]])], | |
83 [ac_cv_c_restrict=$ac_kw]) | |
84 test "$ac_cv_c_restrict" != no && break | |
85 done | |
86 ]) | |
87 AH_VERBATIM([restrict], | |
88 [/* Define to the equivalent of the C99 'restrict' keyword, or to | |
89 nothing if this is not supported. Do not define if restrict is | |
90 supported directly. */ | |
91 #undef restrict | |
92 /* Work around a bug in Sun C++: it does not support _Restrict, even | |
93 though the corresponding Sun C compiler does, which causes | |
94 "#define restrict _Restrict" in the previous line. Perhaps some future | |
95 version of Sun C++ will work with _Restrict; if so, it'll probably | |
96 define __RESTRICT, just as Sun C does. */ | |
97 #if defined __SUNPRO_CC && !defined __RESTRICT | |
98 # define _Restrict | |
99 #endif]) | |
100 case $ac_cv_c_restrict in | |
101 restrict) ;; | |
102 no) AC_DEFINE([restrict], []) ;; | |
103 *) AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;; | |
104 esac | |
105 ]) | |
106 | |
107 # gl_BIGENDIAN | |
108 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd. | |
109 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some | |
110 # macros invoke AC_C_BIGENDIAN with arguments. | |
111 AC_DEFUN([gl_BIGENDIAN], | |
112 [ | |
113 AC_C_BIGENDIAN | |
114 ]) | |
115 | |
116 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it) | |
117 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not | |
118 # output a spurious "(cached)" mark in the midst of other configure output. | |
119 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded | |
120 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair. | |
121 AC_DEFUN([gl_CACHE_VAL_SILENT], | |
122 [ | |
123 saved_as_echo_n="$as_echo_n" | |
124 as_echo_n=':' | |
125 AC_CACHE_VAL([$1], [$2]) | |
126 as_echo_n="$saved_as_echo_n" | |
127 ]) |